13.3 Hoeveel personeel stroomt door naar een oplopend kwalificatieniveau?

Concepten

• Arbeidsovereenkomst
• ODB Kwalificatiewaarde
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.3
2# Parameters: ?peildatum
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    ("Aantal:" AS ?Indeling)
13    (IF(SUM(?noemer_waarde) = 0, "Ongedefinieerd", 100 * SUM(?teller_waarde)/SUM(?noemer_waarde)) AS ?Procent_personeelsleden_met_een_oplopend_kwalificatieniveau)
14{
15    SELECT
16        (IF(?niveau_eerder > 0 && ?niveau_peildatum > 0, 1, 0) AS ?noemer_waarde)
17        (IF( ?niveau_eerder > 0 && ?niveau_peildatum > 0 && ?niveau_eerder < ?niveau_peildatum, 1, 0 ) AS ?teller_waarde)
18    {
19        SELECT
20            ?werknemer
21            (MAX(?op_peildatum) AS ?niveau_peildatum)
22            (MAX(?op_peildatum_eerder) AS ?niveau_eerder)
23        {
24            SELECT
25                ?werknemer
26                ?op_peildatum
27                ?op_peildatum_eerder
28            {   
29                # BIND(xsd:date("2024-01-01") AS ?peildatum)
30                BIND((?peildatum - "P3M"^^xsd:duration) AS ?peildatum_eerder)
31                
32                # Alle werknemers met een zorgverlenerfunctie
33                # Werkovereenkomst-afspraken zonder vestiging tellen ook mee (FO #626)
34                ?overeenkomst
35                    a onz-pers:ArbeidsOvereenkomst ;
36                    onz-pers:heeftOpdrachtnemer ?werknemer ;
37                    onz-g:hasPart ?overeenkomst_afspraak .
38                ?overeenkomst_afspraak
39                    a onz-pers:WerkOvereenkomstAfspraak ;
40                    onz-g:isAbout ?functie ;
41                    onz-g:startDatum ?start_afspraak .
42                ?functie 
43                    a onz-pers:ZorgverlenerFunctie ;
44                    onz-g:hasQuality/onz-g:hasQualityValue ?functie_niveau .
45                
46                OPTIONAL {
47                    ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
48                }
49                
50                # Selecteer kwalificatie niveau en converteer naar integer
51                ?functie_niveau
52                    a onz-pers:ODBKwalificatieWaarde ;
53                    rdfs:label ?niveau .
54                BIND(xsd:integer(REPLACE(?niveau, "\\D+", "")) AS ?niveau_number)
55                
56                # Filter medewerkers met kwalificatieniveau 1 t/m 6
57                FILTER((?niveau_number >= 1) && (?niveau_number <= 6))
58
59                # Filter de functies relevant tijdens de peildatum
60                BIND(IF(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak))), ?niveau_number, 0) AS ?op_peildatum)
61                BIND(IF(?start_afspraak <= ?peildatum_eerder && ((?eind_afspraak >= ?peildatum_eerder) || (!BOUND(?eind_afspraak))), ?niveau_number, 0) AS ?op_peildatum_eerder)
62            }
63        }
64        GROUP BY ?werknemer
65    }
66}